prologues:=2; 
beginfig(1);
u:=0.025cm;
pickup pencircle scaled 1;
%axis
draw (320.0u,1060.0u)--(320.0u,860.0u);
draw (320.0u,860.0u)--(580.0u,860.0u);
label.lft(btex $y$ etex,(320u,1060u));
label.bot(btex $x$ etex,(580u,860u));

%initial budget lines
draw (320.0u,956.0u)--(460.0u,860.0u) dashed evenly scaled 1;
label.lft(btex $b\omega_1$ etex,(320u,956u));
label.bot(btex$\omega_1=\omega_2$ etex,(460u,860u));
draw (320.0u,1060.0u)--(580.0u,860.0u);

%tangency to lower budget line
draw (355u,960u)..(400.0u,900.0u){dir -34}..(460u,880u) dashed evenly scaled 1;
pickup pencircle scaled 4;
draw (400u,900u);
dotlabel.bot(btex $x^*$ etex,(400u,860u));
dotlabel.lft(btex $y^*$ etex,(320u,900u));

%non-mus choice - unlabelled
draw (460u,900u);

%aggregate choice
draw(528.0u,900.0u);

%choice with symmetry
pair choice;
choice:=(1/3)[(460u,860u),(320u,1060u)];
draw choice withcolor green;
label.rt(btex $(x_1,y_1) $ etex,choice+(50u,50u));
%budget line for choice with symmetry
pickup pencircle scaled 1;
drawarrow choice+(50u,50u)..choice+(5u,5u);
draw (460u,860u)--(320u,1060u) dashed evenly scaled 1;

%new budget line for musician
pair mbl_start,mbl_finish;
mbl_start:=(460u,860u);
mbl_finish:=(320u,1000u);
path mus_bud_line;
mus_bud_line:=mbl_start--mbl_finish;
draw mus_bud_line withcolor red;

%non musicians budget line
pair non_budget,non_budget_upper;
tau:=.7;
non_budget:=tau[(580u,860u),(320u,1060u)];
non_budget_upper:=7/6[(460u,860u),non_budget];
draw (460u,860u)--non_budget_upper withcolor blue;

pair newchoice,inter_extreme,aggregate,new_non_choice;
%intersection of musicians budget line and aggreagate, for calulation only
inter_extreme:=whatever[mbl_start,mbl_finish]=whatever[(580u,860u),(320u,1060u)];

%musicians new choice
newchoice:= 6/15[mbl_start,mbl_finish];
%point on aggregate curve with the same y coordinate
tprime[mbl_start,inter_extreme]=newchoice;
aggregate:=tprime[(580u,860u),inter_extreme];
%choice of non-musician
new_non_choice:=whatever[newchoice,aggregate]=whatever[(460u,860u),non_budget_upper];
numeric director;
director:=angle (mbl_start-mbl_finish);
draw newchoice+40dir(director-200)..newchoice{dir director}..newchoice+50dir(director+20) withcolor red;
numeric non_director;
non_director:=angle ((460u,860u)-non_budget_upper);
draw new_non_choice+40dir(non_director-190)..new_non_choice{dir non_director}..new_non_choice+40dir(non_director+20) withcolor blue;
pickup pencircle scaled 4;
draw aggregate;
draw newchoice;
draw new_non_choice;
endfig;
end